OXIESEC PANEL

Name	Size	Modified	Perms
📁 ..	-	03/26/2026 06:59:33 AM	rwxr-xr-x
📄 bash_timestamps.sh	69 bytes	12/12/2023 08:30:54 AM	rw-r--r--
📄 colorgrep.csh	196 bytes	01/31/2022 08:20:26 PM	rw-r--r--
📄 colorgrep.sh	201 bytes	01/31/2022 08:20:26 PM	rw-r--r--
📄 colorls.csh	1.55 KB	03/12/2025 11:38:07 AM	rw-r--r--
📄 colorls.sh	1.4 KB	03/12/2025 11:38:07 AM	rw-r--r--
📄 colorsysstat.csh	69 bytes	10/02/2024 07:53:26 PM	rw-r--r--
📄 colorsysstat.sh	56 bytes	10/02/2024 07:53:26 PM	rw-r--r--
📄 colorxzgrep.csh	162 bytes	06/08/2022 08:25:40 AM	rw-r--r--
📄 colorxzgrep.sh	183 bytes	06/08/2022 08:25:40 AM	rw-r--r--
📄 colorzgrep.csh	216 bytes	10/15/2022 02:24:53 PM	rw-r--r--
📄 colorzgrep.sh	220 bytes	10/15/2022 02:24:53 PM	rw-r--r--
📄 cpanel-user-commands.sh	513 bytes	12/12/2023 08:29:52 AM	rw-r--r--
📄 csh.local	80 bytes	04/03/2024 06:29:31 PM	rw-r--r--
📄 debuginfod.csh	962 bytes	08/25/2025 12:57:59 PM	rw-r--r--
📄 debuginfod.sh	855 bytes	08/25/2025 12:57:59 PM	rw-r--r--
📄 flatpak.sh	831 bytes	04/17/2024 05:19:24 PM	rw-r--r--
📄 gawk.csh	1.08 KB	08/28/2019 06:54:14 PM	rw-r--r--
📄 gawk.sh	757 bytes	08/28/2019 06:54:14 PM	rw-r--r--
📄 lang.csh	3.34 KB	06/23/2020 06:11:43 AM	rw-r--r--
📄 lang.sh	3.11 KB	06/23/2020 06:11:43 AM	rw-r--r--
📄 less.csh	500 bytes	10/02/2024 07:31:20 PM	rw-r--r--
📄 less.sh	253 bytes	10/02/2024 07:31:20 PM	rw-r--r--
📄 locallib.csh	240 bytes	12/12/2023 08:32:50 AM	rwxr-xr-x
📄 locallib.sh	288 bytes	12/12/2023 08:32:50 AM	rwxr-xr-x
📄 modules.csh	109 bytes	09/27/2023 03:12:38 PM	rw-r--r--
📄 modules.sh	479 bytes	09/27/2023 03:12:38 PM	rw-r--r--
📄 scl-init.csh	284 bytes	07/27/2021 03:14:26 PM	rw-r--r--
📄 scl-init.sh	637 bytes	07/27/2021 03:14:26 PM	rw-r--r--
📄 sh.local	81 bytes	04/03/2024 06:29:31 PM	rw-r--r--
📄 which2.csh	120 bytes	08/05/2025 06:14:59 AM	rw-r--r--
📄 which2.sh	627 bytes	08/05/2025 06:14:59 AM	rw-r--r--

Editing: lang.csh

# /etc/profile.d/lang.csh - exports environment variables, and provides fallback
#                          for CJK languages that can't be displayed in console.
#                          Resets the locale if unavailable.

unset LANG_backup

# If unavailable, reset to the default. Do this before reading in any
# explicit user configuration. We simply check if locale emits any
# warnings, and assume that the settings are invalid if it does.
set locale_error=`(/usr/bin/locale >/dev/null) |& cat`
if ("${locale_error}" != "") then
    if (${?LANG}) then
        setenv LANG C.UTF-8
    endif
    unsetenv LC_ALL
    setenv LC_CTYPE C.UTF-8
    setenv LC_NUMERIC C.UTF-8
    setenv LC_TIME C.UTF-8
    setenv LC_COLLATE C.UTF-8
    setenv LC_MONETARY C.UTF-8
    setenv LC_MESSAGES C.UTF-8
    setenv LC_PAPER C.UTF-8
    setenv LC_NAME C.UTF-8
    setenv LC_ADDRESS C.UTF-8
    setenv LC_TELEPHONE C.UTF-8
    setenv LC_MEASUREMENT C.UTF-8
    setenv LC_IDENTIFICATION C.UTF-8
else
    if (${?LANG}) then
        set LANG_backup=${LANG}
    endif
endif

foreach config (/etc/locale.conf "${HOME}/.i18n")
    if (-f "${config}") then
        # NOTE: We are using eval & sed here to avoid invoking of any commands & functions from those files.
        eval `/usr/bin/sed -r -e 's/^[[:blank:]]*([[:upper:]_]+)=([[:print:][:digit:]\._-]+|"[[:print:][:digit:]\._-]+")/setenv \1 \2;/;t;d' ${config}`
    endif
end

if (${?LANG_backup}) then
    setenv LANG "${LANG_backup}"
endif

unset LANG_backup config locale_error

# ----------------------------------------------

# The LC_ALL is not supposed to be set in /etc/locale.conf according to 'man 5 locale.conf'.
# If it is set, then we expect it is user's explicit override (most likely from ~/.i18n file).
# See 'man 7 locale' for more info about LC_ALL.
if (${?LC_ALL}) then
    if (${?LANG}) then
        if (${LC_ALL} != ${LANG}) then
            setenv LC_ALL
        else
            unsetenv LC_ALL
        endif
    else
        unsetenv LC_ALL
    endif
endif

# The ${LANG} manipulation is necessary only in virtual terminal (a.k.a. console - /dev/tty*):
set in_console=`/usr/bin/tty | /usr/bin/grep -vc -e '/dev/tty'`

if (${?LANG} && ${?TERM}) then
    if (${TERM} == 'linux' && $in_console == 0) then
        set utf8_used=`echo ${LANG} | /usr/bin/grep -vc -E -i -e '^.+\.utf-?8$'`

if (${utf8_used} == 0) then
            switch (${LANG})
                case en_IN*:
                    breaksw
                case ja*:
                case ko*:
                case si*:
                case zh*:
                case ar*:
                case fa*:
                case he*:
                case *_IN*:
                    setenv LANG en_US.UTF-8
                    breaksw
            endsw
        else
            switch (${LANG})
                case en_IN*:
                    breaksw
                case ja*:
                case ko*:
                case si*:
                case zh*:
                case ar*:
                case fa*:
                case he*:
                case *_IN*:
                    setenv LANG en_US
                    breaksw
            endsw
        endif

# NOTE: We are not exporting the ${LANG} here again on purpose.
        #       If user starts GUI session from console manually, then
        #       the previously set LANG should be okay to use.
    endif
endif

unset in_console utf8_used